# apache

[Module description]: #module-description

[Setup]: #setup

[Beginning with Apache]: #beginning-with-apache

[Usage]: #usage

[Configuring virtual hosts]: #configuring-virtual-hosts

[Configuring virtual hosts with SSL]: #configuring-virtual-hosts-with-ssl

[Configuring virtual host port and address bindings]: #configuring-virtual-host-port-and-address-bindings

[Configuring virtual hosts for apps and processors]: #configuring-virtual-hosts-for-apps-and-processors

[Configuring IP-based virtual hosts]: #configuring-ip-based-virtual-hosts

[Installing Apache modules]: #installing-apache-modules

[Installing arbitrary modules]: #installing-arbitrary-modules

[Installing specific modules]: #installing-specific-modules

[Configuring FastCGI servers]: #configuring-fastcgi-servers-to-handle-php-files

[Load balancing examples]: #load-balancing-examples

[Reference]: #reference

[Public classes]: #public-classes

[Private classes]: #private-classes

[Public defines]: #public-defines

[Private defines]: #private-defines

[Templates]: #templates

[Limitations]: #limitations

[Development]: #development

[Contributing]: #contributing

[Running tests]: #running-tests

[`AddDefaultCharset`]: http://httpd.apache.org/docs/current/mod/core.html#adddefaultcharset

[`add_listen`]: #add_listen

[`Alias`]: https://httpd.apache.org/docs/current/mod/mod_alias.html#alias

[`AliasMatch`]: https://httpd.apache.org/docs/current/mod/mod_alias.html#aliasmatch

[aliased servers]: https://httpd.apache.org/docs/current/urlmapping.html

[`AllowEncodedSlashes`]: http://httpd.apache.org/docs/current/mod/core.html#allowencodedslashes

[`apache`]: #class-apache

[`apache_version`]: #apache_version

[`apache::balancer`]: #define-apachebalancer

[`apache::balancermember`]: #define-apachebalancermember

[`apache::fastcgi::server`]: #define-apachefastcgiserver

[`apache::mod`]: #define-apachemod

[`apache::mod::<MODULE NAME>`]: #classes-apachemodmodule-name

[`apache::mod::alias`]: #class-apachemodalias

[`apache::mod::auth_cas`]: #class-apachemodauth_cas

[`apache::mod::auth_mellon`]: #class-apachemodauth_mellon

[`apache::mod::disk_cache`]: #class-apachemoddisk_cache

[`apache::mod::event`]: #class-apachemodevent

[`apache::mod::ext_filter`]: #class-apachemodext_filter

[`apache::mod::geoip`]: #class-apachemodgeoip

[`apache::mod::itk`]: #class-apachemoditk

[`apache::mod::passenger`]: #class-apachemodpassenger

[`apache::mod::peruser`]: #class-apachemodperuser

[`apache::mod::prefork`]: #class-apachemodprefork

[`apache::mod::proxy_html`]: #class-apachemodproxy_html

[`apache::mod::security`]: #class-apachemodsecurity

[`apache::mod::shib`]: #class-apachemodshib

[`apache::mod::ssl`]: #class-apachemodssl

[`apache::mod::status`]: #class-apachemodstatus

[`apache::mod::worker`]: #class-apachemodworker

[`apache::mod::wsgi`]: #class-apachemodwsgi

[`apache::params`]: #class-apacheparams

[`apache::version`]: #class-apacheversion

[`apache::vhost`]: #define-apachevhost

[`apache::vhost::WSGIImportScript`]: #wsgiimportscript

[Apache HTTP Server]: http://httpd.apache.org

[Apache modules]: http://httpd.apache.org/docs/current/mod/

[array]: https://docs.puppetlabs.com/puppet/latest/reference/lang_data_array.html

[beaker-rspec]: https://github.com/puppetlabs/beaker-rspec

[certificate revocation list]: http://httpd.apache.org/docs/current/mod/mod_ssl.html#sslcarevocationfile

[certificate revocation list path]: http://httpd.apache.org/docs/current/mod/mod_ssl.html#sslcarevocationpath

[common gateway interface]: http://httpd.apache.org/docs/current/howto/cgi.html

[`confd_dir`]: #confd_dir

[`content`]: #content

[custom error documents]: http://httpd.apache.org/docs/current/custom-error.html

[`custom_fragment`]: #custom_fragment

[`default_mods`]: #default_mods

[`default_ssl_crl`]: #default_ssl_crl

[`default_ssl_crl_path`]: #default_ssl_crl_path

[`default_ssl_vhost`]: #default_ssl_vhost

[`dev_packages`]: #dev_packages

[`directory`]: #directory

[`directories`]: #parameter-directories-for-apachevhost

[`DirectoryIndex`]: http://httpd.apache.org/docs/current/mod/mod_dir.html#directoryindex

[`docroot`]: #docroot

[`docroot_owner`]: #docroot_owner

[`docroot_group`]: #docroot_group

[`DocumentRoot`]: https://httpd.apache.org/docs/current/mod/core.html#documentroot

[`EnableSendfile`]: http://httpd.apache.org/docs/current/mod/core.html#enablesendfile

[`ExpiresByType`]: http://httpd.apache.org/docs/current/mod/mod_expires.html#expiresbytype

[enforcing mode]: http://selinuxproject.org/page/Guide/Mode

[`ensure`]: https://docs.puppetlabs.com/references/latest/type.html#package-attribute-ensure

[exported resources]: http://docs.puppetlabs.com/latest/reference/lang_exported.md

[`ExtendedStatus`]: http://httpd.apache.org/docs/current/mod/core.html#extendedstatus

[Facter]: http://docs.puppetlabs.com/facter/

[FastCGI]: http://www.fastcgi.com/

[FallbackResource]: https://httpd.apache.org/docs/current/mod/mod_dir.html#fallbackresource

[`fallbackresource`]: #fallbackresource

[filter rules]: http://httpd.apache.org/docs/current/filter.html

[`filters`]: #filters

[`ForceType`]: http://httpd.apache.org/docs/current/mod/core.html#forcetype

[GeoIPScanProxyHeaders]: http://dev.maxmind.com/geoip/legacy/mod_geoip2/#Proxy-Related_Directives

[`gentoo/puppet-portage`]: https://github.com/gentoo/puppet-portage

[Hash]: https://docs.puppetlabs.com/puppet/latest/reference/lang_data_hash.html

[`IncludeOptional`]: http://httpd.apache.org/docs/current/mod/core.html#includeoptional

[`Include`]: http://httpd.apache.org/docs/current/mod/core.html#include

[interval syntax]: http://httpd.apache.org/docs/current/mod/mod_expires.html#AltSyn

[`ip`]: #ip

[`ip_based`]: #ip_based

[IP-based virtual hosts]: http://httpd.apache.org/docs/current/vhosts/ip-based.html

[`KeepAlive`]: http://httpd.apache.org/docs/current/mod/core.html#keepalive

[`KeepAliveTimeout`]: http://httpd.apache.org/docs/current/mod/core.html#keepalivetimeout

[`keepalive` parameter]: #keepalive

[`keepalive_timeout`]: #keepalive_timeout

[`lib`]: #lib

[`lib_path`]: #lib_path

[`Listen`]: http://httpd.apache.org/docs/current/bind.html

[`ListenBackLog`]: https://httpd.apache.org/docs/current/mod/mpm_common.html#listenbacklog

[`LoadFile`]: https://httpd.apache.org/docs/current/mod/mod_so.html#loadfile

[`LogFormat`]: https://httpd.apache.org/docs/current/mod/mod_log_config.html#logformat

[`logroot`]: #logroot

[Log security]: http://httpd.apache.org/docs/current/logs.html#security

[`manage_docroot`]: #manage_docroot

[`manage_user`]: #manage_user

[`manage_group`]: #manage_group

[`MaxConnectionsPerChild`]: https://httpd.apache.org/docs/current/mod/mpm_common.html#maxconnectionsperchild

[`max_keepalive_requests`]: #max_keepalive_requests

[`MaxRequestWorkers`]: https://httpd.apache.org/docs/current/mod/mpm_common.html#maxrequestworkers

[`MaxSpareThreads`]: https://httpd.apache.org/docs/current/mod/mpm_common.html#maxsparethreads

[MIME `content-type`]: https://www.iana.org/assignments/media-types/media-types.xhtml

[`MinSpareThreads`]: https://httpd.apache.org/docs/current/mod/mpm_common.html#minsparethreads

[`mod_alias`]: https://httpd.apache.org/docs/current/mod/mod_alias.html

[`mod_auth_cas`]: https://github.com/Jasig/mod_auth_cas

[`mod_auth_kerb`]: http://modauthkerb.sourceforge.net/configure.html

[`mod_authnz_external`]: https://code.google.com/p/mod-auth-external/

[`mod_auth_mellon`]: https://github.com/UNINETT/mod_auth_mellon

[`mod_disk_cache`]: https://httpd.apache.org/docs/2.2/mod/mod_disk_cache.html

[`mod_cache_disk`]: https://httpd.apache.org/docs/current/mod/mod_cache_disk.html

[`mod_expires`]: http://httpd.apache.org/docs/current/mod/mod_expires.html

[`mod_ext_filter`]: http://httpd.apache.org/docs/current/mod/mod_ext_filter.html

[`mod_fcgid`]: https://httpd.apache.org/mod_fcgid/mod/mod_fcgid.html

[`mod_geoip`]: http://dev.maxmind.com/geoip/legacy/mod_geoip2/

[`mod_info`]: https://httpd.apache.org/docs/current/mod/mod_info.html

[`mod_mpm_event`]: https://httpd.apache.org/docs/current/mod/event.html

[`mod_negotiation`]: http://httpd.apache.org/docs/current/mod/mod_negotiation.html

[`mod_pagespeed`]: https://developers.google.com/speed/pagespeed/module/?hl=en

[`mod_php`]: http://php.net/manual/en/book.apache.php

[`mod_proxy`]: https://httpd.apache.org/docs/current/mod/mod_proxy.html

[`mod_proxy_balancer`]: http://httpd.apache.org/docs/current/mod/mod_proxy_balancer.html

[`mod_reqtimeout`]: http://httpd.apache.org/docs/current/mod/mod_reqtimeout.html

[`mod_security`]: https://www.modsecurity.org/

[`mod_ssl`]: http://httpd.apache.org/docs/current/mod/mod_ssl.html

[`mod_status`]: http://httpd.apache.org/docs/current/mod/mod_status.html

[`mod_version`]: http://httpd.apache.org/docs/current/mod/mod_version.html

[`mod_wsgi`]: http://modwsgi.readthedocs.org/en/latest/

[module contribution guide]: http://docs.puppetlabs.com/forge/contributing.html

[`mpm_module`]: #mpm_module

[multi-processing module]: http://httpd.apache.org/docs/current/mpm.html

[name-based virtual hosts]: https://httpd.apache.org/docs/current/vhosts/name-based.html

[open source Puppet]: http://docs.puppetlabs.com/puppet/

[`Options`]: https://httpd.apache.org/docs/current/mod/core.html#options

[`path`]: #path

[`Peruser`]: http://www.freebsd.org/cgi/url.cgi?ports/www/apache22-peruser-mpm/pkg-descr

[`port`]: #port

[`priority`]: #defines-apachevhost

[`ProxyPass`]: http://httpd.apache.org/docs/current/mod/mod_proxy.html#proxypass

[`ProxySet`]: http://httpd.apache.org/docs/current/mod/mod_proxy.html#proxyset

[Puppet Enterprise]: http://docs.puppetlabs.com/pe/

[Puppet Forge]: http://forge.puppetlabs.com

[Puppet Labs]: http://puppetlabs.com

[Puppet module]: http://docs.puppetlabs.com/puppet/latest/reference/modules_fundamentals.html

[Puppet module's code]: https://github.com/puppetlabs/puppetlabs-apache/blob/master/manifests/default_mods.pp

[`purge_configs`]: #purge_configs

[`purge_vhost_dir`]: #purge_vhost_dir

[Python]: https://www.python.org/

[Rack]: http://rack.github.io/

[`rack_base_uris`]: #rack_base_uris

[RFC 2616]: https://www.ietf.org/rfc/rfc2616.txt

[`RequestReadTimeout`]: http://httpd.apache.org/docs/current/mod/mod_reqtimeout.html#requestreadtimeout

[rspec-puppet]: http://rspec-puppet.com/

[`ScriptAlias`]: https://httpd.apache.org/docs/current/mod/mod_alias.html#scriptalias

[`ScriptAliasMatch`]: https://httpd.apache.org/docs/current/mod/mod_alias.html#scriptaliasmatch

[`scriptalias`]: #scriptalias

[SELinux]: http://selinuxproject.org/

[`ServerAdmin`]: http://httpd.apache.org/docs/current/mod/core.html#serveradmin

[`serveraliases`]: #serveraliases

[`ServerLimit`]: https://httpd.apache.org/docs/current/mod/mpm_common.html#serverlimit

[`ServerName`]: http://httpd.apache.org/docs/current/mod/core.html#servername

[`ServerRoot`]: http://httpd.apache.org/docs/current/mod/core.html#serverroot

[`ServerTokens`]: http://httpd.apache.org/docs/current/mod/core.html#servertokens

[`ServerSignature`]: http://httpd.apache.org/docs/current/mod/core.html#serversignature

[Service attribute restart]: http://docs.puppetlabs.com/references/latest/type.html#service-attribute-restart

[`source`]: #source

[`SSLCARevocationCheck`]: http://httpd.apache.org/docs/current/mod/mod_ssl.html#sslcarevocationcheck

[SSL certificate key file]: http://httpd.apache.org/docs/current/mod/mod_ssl.html#sslcertificatekeyfile

[SSL chain]: https://httpd.apache.org/docs/current/mod/mod_ssl.html#sslcertificatechainfile

[SSL encryption]: https://httpd.apache.org/docs/current/ssl/index.html

[`ssl`]: #ssl

[`ssl_cert`]: #ssl_cert

[`ssl_compression`]: #ssl_compression

[`ssl_key`]: #ssl_key

[`StartServers`]: https://httpd.apache.org/docs/current/mod/mpm_common.html#startservers

[suPHP]: http://www.suphp.org/Home.html

[`suphp_addhandler`]: #suphp_addhandler

[`suphp_configpath`]: #suphp_configpath

[`suphp_engine`]: #suphp_engine

[supported operating system]: https://forge.puppetlabs.com/supported#puppet-supported-modules-compatibility-matrix

[`ThreadLimit`]: http://httpd.apache.org/docs/current/mod/mpm_common.html#threadlimit

[`ThreadsPerChild`]: https://httpd.apache.org/docs/current/mod/mpm_common.html#threadsperchild

[`TimeOut`]: http://httpd.apache.org/docs/current/mod/core.html#timeout

[template]: http://docs.puppetlabs.com/puppet/latest/reference/lang_template.html

[`TraceEnable`]: http://httpd.apache.org/docs/current/mod/core.html#traceenable

[`verify_config`]: #verify_config

[`vhost`]: #define-apachevhost

[`vhost_dir`]: #vhost_dir

[`virtual_docroot`]: #virtual_docroot

[Web Server Gateway Interface]: https://www.python.org/dev/peps/pep-3333/#abstract

[`WSGIPythonPath`]: https://code.google.com/p/modwsgi/wiki/ConfigurationDirectives#WSGIPythonPath

[`WSGIPythonHome`]: https://code.google.com/p/modwsgi/wiki/ConfigurationDirectives#WSGIPythonHome

#### Table of Contents

1. [Module description - What is the apache module, and what does it do?][Module description]

2. [Setup - The basics of getting started with apache][Setup]

    - [Beginning with Apache - Installation][Beginning with Apache]

3. [Usage - The classes and defined types available for configuration][Usage]

    - [Configuring virtual hosts - Examples to help get started][Configuring virtual hosts]

    - [Configuring FastCGI servers to handle PHP files][Configuring FastCGI servers]

    - [Load balancing with exported and non-exported resources][Load balancing examples]

4. [Reference - An under-the-hood peek at what the module is doing and how][Reference]

    - [Public classes][]

    - [Private classes][]

    - [Public defines][]

    - [Private defines][]

    - [Templates][]

5. [Limitations - OS compatibility, etc.][Limitations]

6. [Development - Guide for contributing to the module][Development]

    - [Contributing to the apache module][Contributing]

    - [Running tests - A quick guide][Running tests]

## Module description

[Apache HTTP Server][] (also called Apache HTTPD, or simply Apache) is a widely used web server. This [Puppet module][] simplifies the task of creating configurations to manage Apache servers in your infrastructure. It can configure and manage a range of virtual host setups and provides a streamlined way to install and configure [Apache modules][].

## Setup

**What the apache Puppet module affects:**

- Configuration files and directories (created and written to)

  - **WARNING**: Configurations *not* managed by Puppet will be purged.

- Package/service/configuration files for Apache

- Apache modules

- Virtual hosts

- Listened-to ports

- `/etc/make.conf` on FreeBSD and Gentoo

On Gentoo, this module depends on the [`gentoo/puppet-portage`][] Puppet module. Note that while several options apply or enable certain features and settings for Gentoo, it is not a [supported operating system][] for this module.

**Note**: This module modifies Apache configuration files and directories and purges any configuration not managed by Puppet. Apache configuration should be managed by Puppet, as unmanaged configuration files can cause unexpected failures.

To temporarily disable full Puppet management, set the [`purge_configs`][] parameter in the [`apache`][] class declaration to 'false'. We recommend using this only as a temporary means of saving and relocating customized configurations.

### Beginning with Apache

To have Puppet install Apache with the default parameters, declare the [`apache`][] class:

~~~ puppet

class { 'apache': }

~~~

The Puppet module applies a default configuration based on your operating system; Debian, Red Hat, FreeBSD, and Gentoo systems each have unique default configurations. These defaults work in testing environments but are not suggested for production, and Puppet recommends customizing the class's parameters to suit your site. Use the [Reference](#reference) section to find information about the class's parameters and their default values.

You can customize parameters when declaring the `apache` class. For instance, this declaration installs Apache without the apache module's [default virtual host configuration][Configuring virtual hosts], allowing you to customize all Apache virtual hosts:

~~~ puppet

class { 'apache':

  default_vhost => false,

}

~~~

## Usage

### Configuring a virtual host

The default [`apache`][] class sets up a virtual host on port 80, listening on all interfaces and serving the [`docroot`][] parameter's default directory of `/var/www`.

**Note**: See the [`apache::vhost`][] define's reference for a list of all virtual host parameters.

To configure basic [name-based virtual hosts][], specify the [`port`][] and [`docroot`][] parameters in the [`apache::vhost`][] define:

~~~ puppet

apache::vhost { 'vhost.example.com':

  port    => '80',

  docroot => '/var/www/vhost',

}

~~~

**Note**: Apache processes virtual hosts in alphabetical order, and server administrators can prioritize Apache's virtual host processing by prefixing a virtual host's configuration file name with a number. The [`apache::vhost`][] define applies a default [`priority`][] of 15, which Puppet interprets by prefixing the virtual host's file name with `15-`. This all means that if multiple sites have the same priority, or if you disable priority numbers by setting the `priority` parameter's value to 'false', Apache still processes virtual hosts in alphabetical order.

To configure user and group ownership for `docroot`, use the [`docroot_owner`][] and [`docroot_group`][] parameters:

~~~ puppet

apache::vhost { 'user.example.com':

  port          => '80',

  docroot       => '/var/www/user',

  docroot_owner => 'www-data',

  docroot_group => 'www-data',

}

~~~

#### Configuring virtual hosts with SSL

To configure a virtual host to use [SSL encryption][] and default SSL certificates, set the [`ssl`][] parameter. You must also specify the [`port`][] parameter, typically with a value of '443', to accommodate HTTPS requests:

~~~ puppet

apache::vhost { 'ssl.example.com':

  port    => '443',

  docroot => '/var/www/ssl',

  ssl     => true,

}

~~~

To configure a virtual host to use SSL and specific SSL certificates, use the paths to the certificate and key in the [`ssl_cert`][] and [`ssl_key`][] parameters, respectively:

~~~ puppet

apache::vhost { 'cert.example.com':

  port     => '443',

  docroot  => '/var/www/cert',

  ssl      => true,

  ssl_cert => '/etc/ssl/fourth.example.com.cert',

  ssl_key  => '/etc/ssl/fourth.example.com.key',

}

~~~

To configure a mix of SSL and unencrypted virtual hosts at the same domain, declare them with separate [`apache::vhost`] defines:

~~~ puppet

# The non-ssl virtual host

apache::vhost { 'mix.example.com non-ssl':

  servername => 'mix.example.com',

  port       => '80',

  docroot    => '/var/www/mix',

}

# The SSL virtual host at the same domain

apache::vhost { 'mix.example.com ssl':

  servername => 'mix.example.com',

  port       => '443',

  docroot    => '/var/www/mix',

  ssl        => true,

}

~~~

To configure a virtual host to redirect unencrypted connections to SSL, declare them with separate [`apache::vhost`] defines and redirect unencrypted requests to the virtual host with SSL enabled:

~~~ puppet

apache::vhost { 'redirect.example.com non-ssl':

  servername      => 'redirect.example.com',

  port            => '80',

  docroot         => '/var/www/redirect',

  redirect_status => 'permanent',

  redirect_dest   => 'https://redirect.example.com/'

}

apache::vhost { 'redirect.example.com ssl':

  servername => 'redirect.example.com',

  port       => '443',

  docroot    => '/var/www/redirect',

  ssl        => true,

}

~~~

#### Configuring virtual host port and address bindings

Virtual hosts listen on all IP addresses ('*') by default. To configure the virtual host to listen on a specific IP address, use the [`ip`][] parameter:

~~~ puppet

apache::vhost { 'ip.example.com':

  ip      => '127.0.0.1',

  port    => '80',

  docroot => '/var/www/ip',

}

~~~

It is also possible to configure more than one IP address per vhost by using an array of IP addresses for the [`ip`][] parameter:

~~~ puppet

apache::vhost { 'ip.example.com':

  ip      => ['127.0.0.1','169.254.1.1'],

  port    => '80',

  docroot => '/var/www/ip',

}

~~~

To configure a virtual host with [aliased servers][], refer to the aliases using the [`serveraliases`][] parameter:

~~~ puppet

apache::vhost { 'aliases.example.com':

  serveraliases => [

    'aliases.example.org',

    'aliases.example.net',

  ],

  port          => '80',

  docroot       => '/var/www/aliases',

}

~~~

To set up a virtual host with a wildcard alias for the subdomain mapped to a same-named directory, such as 'http://example.com.loc' mapped to `/var/www/example.com`, define the wildcard alias using the [`serveraliases`][] parameter and the document root with the [`virtual_docroot`][] parameter:

~~~ puppet

apache::vhost { 'subdomain.loc':

  vhost_name      => '*',

  port            => '80',

  virtual_docroot => '/var/www/%-2+',

  docroot         => '/var/www',

  serveraliases   => ['*.loc',],

}

~~~

To configure a virtual host with [filter rules][], pass the filter directives as an [array][] using the [`filters`][] parameter:

~~~ puppet

apache::vhost { 'subdomain.loc':

  port    => '80',

  filters => [

    'FilterDeclare  COMPRESS',

    'FilterProvider COMPRESS DEFLATE resp=Content-Type $text/html',

    'FilterChain    COMPRESS',

    'FilterProtocol COMPRESS DEFLATE change=yes;byteranges=no',

  ],

  docroot => '/var/www/html',

}

~~~

#### Configuring virtual hosts for apps and processors

To set up a virtual host with [suPHP][], use the [`suphp_engine`][] parameter to enable the suPHP engine, [`suphp_addhandler`][] parameter to define a MIME type, [`suphp_configpath`][] to set which path suPHP passes to the PHP interpreter, and the [`directory`][] parameter to configure Directory, File, and Location directive blocks:

~~~ puppet

apache::vhost { 'suphp.example.com':

  port             => '80',

  docroot          => '/home/appuser/myphpapp',

  suphp_addhandler => 'x-httpd-php',

  suphp_engine     => 'on',

  suphp_configpath => '/etc/php5/apache2',

  directories      => [

    { 'path'  => '/home/appuser/myphpapp',

      'suphp' => {

        user  => 'myappuser',

        group => 'myappgroup',

      },

    },

  ],

}

~~~

You can use a set of parameters to configure a virtual host to use the [Web Server Gateway Interface][] (WSGI) for [Python][] applications:

~~~ puppet

apache::vhost { 'wsgi.example.com':

  port                        => '80',

  docroot                     => '/var/www/pythonapp',

  wsgi_application_group      => '%{GLOBAL}',

  wsgi_daemon_process         => 'wsgi',

  wsgi_daemon_process_options => {

    processes    => '2',

    threads      => '15',

    display-name => '%{GROUP}',

  },

  wsgi_import_script          => '/var/www/demo.wsgi',

  wsgi_import_script_options  => {

    process-group     => 'wsgi',

    application-group => '%{GLOBAL}',

  },

  wsgi_process_group          => 'wsgi',

  wsgi_script_aliases         => { '/' => '/var/www/demo.wsgi' },

}

~~~

Starting in Apache 2.2.16, Apache supports [FallbackResource][], a simple replacement for common RewriteRules. You can set a FallbackResource using the [`fallbackresource`][] parameter:

~~~ puppet

apache::vhost { 'wordpress.example.com':

  port             => '80',

  docroot          => '/var/www/wordpress',

  fallbackresource => '/index.php',

}

~~~

**Note**: The `fallbackresource` parameter only supports the 'disabled' value since Apache 2.2.24.

To configure a virtual host with a designated directory for [Common Gateway Interface][] (CGI) files, use the [`scriptalias`][] parameter to define the `cgi-bin` path:

~~~ puppet

apache::vhost { 'cgi.example.com':

  port        => '80',

  docroot     => '/var/www/cgi',

  scriptalias => '/usr/lib/cgi-bin',

}

~~~

To configure a virtual host for [Rack][], use the [`rack_base_uris`][] parameter:

~~~ puppet

apache::vhost { 'rack.example.com':

  port           => '80',

  docroot        => '/var/www/rack',

  rack_base_uris => ['/rackapp1', '/rackapp2'],